VBA如何使用主过程和子过程

当你大VBA程序得越来越大，要很好地维护这么多的代码行是很困难的。要让你的程序容易编写、理解和改变，你就应该使用井井有条的结构化程序。如何创建结构化程序？你只要简单地将大问题分成一些可以同时执行的小问题就行。在VBA中，你可以通过创建一个主过程和一个或多个子过程来实现它。因为主过程和子过程都是子程序，所以你都可以用关键字Sub将它们声明。主过程可以调用所需的子过程，并且将参数传递给它们。它也可以调用函数。下面的例子显示过程AboutUser。该过程要求用户姓和名，并且将姓和名从全名中分离出来。最后的语句显示用户的姓，随后是逗号和名。你再读下去，该过程将被分割成几个任务，以示范使用主过程，子过程和函数的概念。

Sub AboutUser()
    Dim fullName As String
    Dim firstName As String
    Dim lastName As String
    Dim space As Integer
    get input from user 从用户获取信息
    fullName = InputBox("Enter first and last name:")
    get first and last name strings 获得姓和名字符串
    space = InStr(fullName, " ")
    firstName = Left(fullName, space – 1)
    lastName = Right(fullName, Len(fullName) – space)
    display last name, first name 显示姓和名
    MsgBox lastName & ", " & firstName
End Sub

过程AboutUser可以分割为一些细小的任务。第一个任务便是获取用户的全名；下一个任务则需要你将用户提供的数据分割为两个字符串：姓和名，这些任务可以交给不同的函数（例如：GetLast和GetFirst）；最后的任务是显示重新排列的姓名字符串信息。既然你已经知道了你应该注重于哪些任务，我们现在就来看看如何完成每个任务。

1.  在你当前的VBA工程里面添加一个模块，并重命名为Sample9

2.  在Sample9模块窗口里面输入下列过程AboutUserMaster：

Sub AboutUserMaster()
    Dim first As String, last As String, full As String
    Call GetUserName(full)
    first = GetFirst(full)
    last = GetLast(full)
    Call DisplayLastFirst(first, last)
End Sub

上面显示的主过程通过调用适当的子程序和函数来控制程序的主流程。该主过程以变量生命开始，第一条语句Call GetUserName (full)调用子过程GetUserName（见第三步）并且传递给一参数——变量full的内容。

因为变量在执行调用语句之前没有赋与任何值，所以它的值是一个空字符串（“ ”）。注意，子过程的名称在Call之后。尽管你在调用过程时并没有要求使用关键字Call，但是，你在调用一个需要参数的过程时就必须使用它。参数列表必须包括在括号里面。

3.  输入下面的GetUserName子程序：

Sub GetUserName(fullName As String)
    fullName = InputBox("Enter first and last name:")
End Sub

过程GetUserName示范了两个非常重要的VB编程概念：如何传递参数给一子程序以及如何将值从子程序传递回给主调过程。

在主过程（见第二步）中，你调用了过程GetUserName，并且将其作为一参数传递：变量full。该变量被参数fullName接收，该参数子过程GetUserName的Sub语句里声明了。因为在VB调用子过程GetUserName的时候，变量full包含一空字符串，参数fullName同样也接收了这个空字符串。当VB显示对话框并且获得用户的姓名时，这个姓名将赋给参数fullName。赋给参数的值被传递回给子过程执行后的匹配参数。因此，当VB返回主过程时，变量full就回包含用户的姓名。

传递给子过程的自变量将被其参数接收。注意，参数名称（fullName）后面紧跟着数据类型的声明（AsString）。虽然，参数的数据类型必须和相匹配的自变量的数据类型一致，但是，不同的名称还是可以使用给一个自变量和它相应的参数。

技巧：自变量（Arguments）和参数（Parameters）

①自变量是传递给一个子过程的变量，常量或表达式

②参数则只是接收值并传递给子过程的变量

4.  输入下述函数GetFirst：

Function GetFirst(fullName As String)
    Dim space As Integer
    space = InStr(fullName, " ")
    GetFirst = Left(fullName, space - 1)
End Function

主过程中的第二条语句（见第二步）first=GetFirst(full)，将变量full的值传递给函数GetFirst。函数的参数fullName接收到该值。要从用户提供的数据里分出姓和名，你就必须找到姓和名中间的空格。因此，该函数的开头是当地变量space的声明，下条语句则使用VBA内置函数InStr返回字符串fullName里空格（“ ”）的位置。然后将获得的数字赋值给变量space。最后，Left函数用来提取字符串fullName从左到某特定个数（space -1）的字符。名的长度比储存在变量space的值少一个字符。函数的结果（用户的名）赋值给函数名。当VB返回主过程时，它就将结果放置于变量first。

5.  输入下列函数GetLast：

Function GetLast(fullName As String)
    Dim space As Integer
    space = InStr(fullName, " ")
    GetLast = Right(fullName, Len(fullName) - space)
End Function

主过程里面的第三条语句（见第二步）last=GetLast(full)，将变量full的值传递给函数GetLast。该函数的目的是提取用户提供的数据中的用户的姓。函数GetLast使用内置函数Len来计算字符串fullName的总字符数。函数Right提取字符串fullName从右边某个特定字符开始（Len(fullName)–space）的字符。然后，获得的字符串赋值给函数名称，一旦返回主过程，它就储存于变量last。

6.  输入下述子过程DisplayLastFirst：

Sub DisplayLastFirst(firstName As String, lastName As String)
    MsgBox lastName & ", " & firstName
End Sub

主过程里面的第四条语句（见第二步）Call     DisplayLastFirst(first, last)，调用子过程
DisplayLastFirst并且将两个自变量：first和last。为了接收这些自变量，子过程
DisplayLastFirst和两个相匹配的参数（firstName和lastName）一起被声明了。回想我们前面说过，不同的名称可以用在自变量和相应的参数上。然后子过程DisplayLastFirst显示用户的姓，逗号，和名。

技巧：使用子过程的好处
①维护多个子过程要比维护一个大过程要容易得多
②由一个子过程执行的任务可以给好几个过程使用
③每个子过程再放入主过程里之前就被单独测试
„④多个程序员可以负责各自的子过程，这些子过程再构建一个大的程序

在本章里，你学习了子过程和函数之间的区别：子过程执行操作；函数返回数值。而且你可以通过录制或者输入来创建子过程，函数则不可以录制，因为它们可能需要参数，你必须手动输入。你看到了从工作表或者其他VB过程调用的函数实例。

你学习了如何给函数传递自变量，决定函数结果的数据类型。你在你的VBA关键字的系统里增加了ByVal，ByRef和Optional等关键字。你也看到如何将问题分割为更小更简单的任务，以使你的程序更容易理解。最后，你学习了子过程如何在参数的帮助下，将数值传递回到主调过程。

过了本章后，你应该能够创建适合你特定需要的你自己的自定义函数了。你应该可以通过使用MsgBox和InputBox函数轻松地和用户互动。